Useful GBD user-defined commands for Objective-C

tags:

I’ve been putting together some gdb commands to aid gdb debugging. Here’s my current list:

My application has a number of threads and when one asserts it’s not obvious which is the culprit. I got pretty tired of typing “thread apply all bt” all the time, so this is just an alias for that.

    define tbt
        thread apply all bt
    end

    document tbt
        Issues "thread apply all bt", thus showing the backtraces for all threads
    end

It’s also useful to know the true class of an instance. Simply printing the variable prints its declared type. Since Objective-C is dynamic this may or may not be the actual type of the instance. This sends a class message to the object and prints that.

    define pc
        po [$arg0 class]
    end

    document pc
        Takes one argument and prints its class by sending it the class message.
    end

I find the NSDate compare: method a constant headache. For some reason my brain just hates converting comparison operators into NSComparsionResult values. Worse, in gdb they’re just integer literals. This helps a bit. It takes two dates and prints the symbolic NSComparisonResult.

    define cdate
        set $cdate_result = (int)[$arg0 compare:$arg1]
        if($cdate_result == NSOrderedAscending)
            printf "NSOrderedAscending\n"
        end
        if($cdate_result == NSOrderedSame)
            printf "NSOrderedSame\n"
        end
        if($cdate_result == NSOrderedDescending)
            printf "NSOrderedDescending\n"
        end
    end

    document cdate
        Sends a compare: message to arg0 with arg1 as the argument and prints the
        symbolic result
    end